	.file	"strrchr.s"
/*
 * $Copyright:	$
 * Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
 * Sequent Computer Systems, Inc.   All rights reserved.
 *  
 * This software is furnished under a license and may be used
 * only in accordance with the terms of that license and with the
 * inclusion of the above copyright notice.   This software may not
 * be provided or otherwise made available to, or used by, any
 * other person.  No title to or ownership of the software is
 * hereby transferred.
 *
 */

/*	Copyright (c) 1986 AT&T	*/
/*	All Rights Reserved	*/

/*	THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF AT&T	*/
/*	The copyright notice above does not evidence any	*/
/*	actual or intended publication of such source code.	*/

	.ident	"@(#)$Header: strrchr.s 1.2 89/10/10 $"

/*
 * Return the ptr in sp at which the character c last
 * appears; NULL if not found
 */

/*
 *	char *
 *	strrchr(sp, c)
 *	register char *sp, c;
 *	{
 *		register char *r;
 *	
 *		r = NULL;
 *		do {
 *			if(*sp == c)
 *				r = sp;
 *		} while(*sp++);
 *		return(r);
 *	}
 */

#include "sys.s"

ENTRY(strrchr)
	movl	%edi,%edx	/* save %edi */
	movl	SPARG0,%edi	/* %edi = sp */
	xorl	%eax,%eax	/* %eax = null char */
	movl	$-1,%ecx	/* %ecx = large count */
	repnz ;	scab		/* search for null char */
	decl	%edi		/* backup to null char */
	notl	%ecx		/* %ecx = length of sp */
	movb	SPARG1,%al	/* %al = char sought */
	std			/* set direction flag for backwards */
	repnz ;	scab		/* scan backwards for char */
	cld			/* clear direction flag */
	jnz	.notfound	/* was char found ? */
	leal	1(%edi),%eax	/* return address of match */
	movl	%edx,%edi	/* restore %edi */
	ret
.notfound:
	xorl	%eax,%eax	/* return zero */
	movl	%edx,%edi	/* restore %edi */
	ret
