	.file	"strchr.s"
/*
 * $Copyright:	$
 * Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
 * Sequent Computer Systems, Inc.   All rights reserved.
 *  
 * This software is furnished under a license and may be used
 * only in accordance with the terms of that license and with the
 * inclusion of the above copyright notice.   This software may not
 * be provided or otherwise made available to, or used by, any
 * other person.  No title to or ownership of the software is
 * hereby transferred.
 *
 */

/*	Copyright (c) 1986 AT&T	*/
/*	All Rights Reserved	*/

/*	THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF AT&T	*/
/*	The copyright notice above does not evidence any	*/
/*	actual or intended publication of such source code.	*/

	.ident	"@(#)$Header: strchr.s 1.2 89/10/10 $"

/*
 * Return the ptr in sp at which the character c appears;
 * NULL if not found
 */

/*
 *	char *
 *	strchr(sp, c)
 *	register char *sp, c;
 *	{
 *		do {
 *			if(*sp == c)
 *				return(sp);
 *		} while(*sp++);
 *		return(0);
 *	}
 */

#include "sys.s"

#define	STRCHR	slodb ; cmpb %al,%cl ; je .found; testb %al,%al ; jz .null

ENTRY(strchr)
	movl	%esi,%edx	/* save %esi */
	movl	SPARG0,%esi	/* %esi = address of string */
	movb	SPARG1,%cl	/*  %cl = char to search for */

.loop:
	STRCHR
	STRCHR
	STRCHR
	STRCHR
	STRCHR
	STRCHR
	STRCHR
	STRCHR
	jmp	.loop

.null:
	xorl	%eax,%eax	/* return zero */
	movl	%edx,%esi	/* restore %esi */
	ret

.found:
	leal	-1(%esi),%eax	/* return address of match */
	movl	%edx,%esi	/* restore %esi */
	ret
