	.file	"strncpy.s"
/*
 * $Copyright:	$
 * Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
 * Sequent Computer Systems, Inc.   All rights reserved.
 *  
 * This software is furnished under a license and may be used
 * only in accordance with the terms of that license and with the
 * inclusion of the above copyright notice.   This software may not
 * be provided or otherwise made available to, or used by, any
 * other person.  No title to or ownership of the software is
 * hereby transferred.
 *
 */

/*	Copyright (c) 1986 AT&T	*/
/*	All Rights Reserved	*/

/*	THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF AT&T	*/
/*	The copyright notice above does not evidence any	*/
/*	actual or intended publication of such source code.	*/

	.ident	"@(#)$Header: strncpy.s 1.2 89/10/10 $"

/*
 * Copy s2 to s1, truncating or null-padding to always copy n bytes
 * return s1
 */

/*	#include <sys/types.h>
 *	char *
 *	strncpy(s1, s2, n)
 *	register char *s1, *s2;
 *	register size_t n;
 *	{
 *		register char *os1 = s1;
 *	
 *		n++;				
 *		while ((--n > 0) &&  ((*s1++ = *s2++) != '\0'))
 *			;
 *		if (n > 0)
 *			while (--n > 0)
 *				*s1++ = '\0';
 *		return (os1);
 *	}
 */

#include "sys.s"

ENTRY(strncpy)
	pushl	%edi		/* save %edi */
	pushl	%esi		/*      %esi */
	movl	8+SPARG1,%edi	/* %edi = s2 */
	movl	8+SPARG2,%ecx	/* %ecx = n */
	xorl	%eax,%eax	/* %al = null search char */
	repnz ;	scab
	movl	%ecx,%edx	/* %edx = bytes to zero later */
	movl	%edi,%ecx	/* %ecx = address after source */
	movl	8+SPARG1,%esi	/* %esi = s2 */
	subl	%esi,%ecx	/* %ecx = length to move */
	movl	12(%esp),%edi	/* %edi = destination string address */
	movl	%ecx,%eax	/* %eax = length to move */
	shrl	$2,%ecx		/* %ecx = words to move */
	rep ;	smovl
	movl	%eax,%ecx	/* %ecx = length to move */
	andl	$3,%ecx		/* %ecx = leftover bytes to move */
	rep ;	smovb
	movl	%edx,%ecx	/* %edx = leftover bytes to null */
	xorl	%eax,%eax	/* %eax = null */
	rep ;	sstob		/* store nulls at end */
	popl	%esi		/* restore %esi */
	popl	%edi		/*         %edi */
	movl	SPARG0,%eax	/* return s1 */
	ret
