	.file	"memchr.s"
/*
 * $Copyright:	$
 * Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
 * Sequent Computer Systems, Inc.   All rights reserved.
 *  
 * This software is furnished under a license and may be used
 * only in accordance with the terms of that license and with the
 * inclusion of the above copyright notice.   This software may not
 * be provided or otherwise made available to, or used by, any
 * other person.  No title to or ownership of the software is
 * hereby transferred.
 *
 */

/*	Copyright (c) 1986 AT&T	*/
/*	All Rights Reserved	*/

/*	THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF AT&T	*/
/*	The copyright notice above does not evidence any	*/
/*	actual or intended publication of such source code.	*/

	.ident	"@(#)$Header: memchr.s 1.2 89/10/10 $"

/*
 * Return the ptr in sp at which the character c appears;
 *   NULL if not found in n chars; don't stop at \0.
 */

/*
 *	char *
 *	memchr(sp, c, n)
 *	register char *sp, c;
 *	register int n;
 *	{
 *		while (--n >= 0)
 *			if (*sp++ == c)
 *				return (--sp);
 *		return (0);
 *	}
 */

#include "sys.s"

ENTRY(memchr)
	movl	%edi,%edx		/* save %edi			*/
	movl	SPARG0,%edi		/* %edi = destination		*/
	movb	SPARG1,%al		/*  %al = byte sought		*/
	movl	SPARG2,%ecx		/* %ecx = number of bytes	*/
	testl	%ecx,%ecx		/* count of zero returns zero	*/ 
	jz	.notfound
	repnz ; scab			/* search for %al		*/
	jne	.notfound		/* search failed		*/
	movl	%edi,%eax		/* search found it		*/
	decl	%eax			/* search increments after finding it */
	movl	%edx,%edi		/* restore %edi			*/
	ret

.notfound:
	xorl	%eax,%eax		/* return 0			*/
	movl	%edx,%edi		/* restore %edi			*/
	ret
