	.file	"strcmp.s"
/*
 * $Copyright:	$
 * Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
 * Sequent Computer Systems, Inc.   All rights reserved.
 *  
 * This software is furnished under a license and may be used
 * only in accordance with the terms of that license and with the
 * inclusion of the above copyright notice.   This software may not
 * be provided or otherwise made available to, or used by, any
 * other person.  No title to or ownership of the software is
 * hereby transferred.
 *
 */

/*	Copyright (c) 1984 AT&T	*/
/*	All Rights Reserved	*/

/*	THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF AT&T	*/
/*	The copyright notice above does not evidence any	*/
/*	actual or intended publication of such source code.	*/

	.ident	"@(#)$Header: strcmp.s 1.4 90/05/03 $"

/* Fast assembler language version of the following C-program for	*/
/*			strcmp						*/
/* which represents the `standard' for the C-library.			*/

/*
 * Compare strings:  s1>s2: >0  s1==s2: 0  s1<s2: <0
 */

/*
 *	int
 *	strcmp(s1, s2)
 *	register char *s1, *s2;
 *	{
 *	
 *		if(s1 == s2)
 *			return(0);
 *		while(*s1 == *s2++)
 *			if(*s1++ == '\0')
 *				return(0);
 *		return((unsigned)*s1 - (unsigned)*--s2);
 *	}
 */

#include "sys.s"

/ unroll the loop for speed
#define	STRCMP(cond,label) \
	slodb ; scab ; jne .nequal ; testb %al,%al ; cond label

ENTRY(strcmp)
	movl	%edi,%edx	/* save %edi */
	movl	%esi,%ecx	/* save %esi */
	movl	SPARG0,%esi	/* %esi = s1 */
	movl	SPARG1,%edi	/* %edi = s2 */
	cmpl	%esi,%edi	/* s1 == s2? */
	je	.equal

.loop:
	STRCMP(jz,.equal)
	STRCMP(jz,.equal)
	STRCMP(jz,.equal)
	STRCMP(jz,.equal)
	STRCMP(jz,.equal)
	STRCMP(jz,.equal)
	STRCMP(jz,.equal)
	STRCMP(jnz,.loop)
				/* fall into ... */
.equal:
	movl	%edx,%edi	/* restore %edi */
	movl	%ecx,%esi	/*	   %esi */
	xorl	%eax,%eax	/* return zero */
	ret
	
.nequal:
	movzbl	%al,%eax	/* no sign extension */
	movl	%ecx,%esi	/* restore %esi */
	movzbl	-1(%edi),%ecx	/* %ecx = *s2 */
	movl	%edx,%edi	/* restore %edi */
	subl	%ecx,%eax	/* *s1 - *s2 */
	ret
