.\" $Copyright:	$
.\" Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
.\" Sequent Computer Systems, Inc.   All rights reserved.
.\"  
.\" This software is furnished under a license and may be used
.\" only in accordance with the terms of that license and with the
.\" inclusion of the above copyright notice.   This software may not
.\" be provided or otherwise made available to, or used by, any
.\" other person.  No title to or ownership of the software is
.\" hereby transferred.
...
. \" $Header: ssb 1.3 86/03/06 $
.SH
Appendix B: Yacc Input Syntax
.PP
This Appendix has a description of the Yacc input syntax, as a Yacc specification.
Context dependencies, etc., are not considered.
Ironically, the Yacc input specification language
is most naturally specified as an LR(2) grammar; the sticky
part comes when an identifier is seen in a rule, immediately
following an action.
If this identifier is followed by a colon, it is the start of the
next rule; otherwise
it is a continuation of the current rule, which just happens to have
an action embedded in it.
As implemented, the lexical analyzer looks
ahead after seeing an identifier, and
decide whether the next token (skipping blanks, newlines, comments, etc.)
is a colon.
If so, it returns the token C_IDENTIFIER.
Otherwise, it returns IDENTIFIER.
Literals (quoted strings) are also returned as IDENTIFIERS,
but never as part of C_IDENTIFIERs.
.sp
.nf
.ta .6i 1.2i 1.8i 2.4i 3i 3.6i

            /*  grammar  for  the  input  to  Yacc  */

	/*  basic  entities  */
%token	IDENTIFIER	/*   includes  identifiers   and  literals  */
%token	C_IDENTIFIER	/*    identifier  (but  not  literal)  followed  by  colon    */
%token	NUMBER		/*    [0-9]+    */

	/*  reserved  words:    %type  =>  TYPE,  %left  =>  LEFT,  etc.  */

%token	LEFT  RIGHT  NONASSOC  TOKEN  PREC  TYPE  START  UNION

%token	MARK	/*  the  %%  mark  */
%token	LCURL	/*  the  %{  mark  */
%token	RCURL	/*  the  %}  mark  */

	/*  ascii  character  literals  stand  for  themselves  */

%start	spec

%%

spec	:	defs  MARK  rules  tail
	;

tail	:	MARK	{    \f2In  this  action,  eat  up  the  rest  of  the  file\f1    }
	|	/*  empty:  the  second  MARK  is  optional  */
	;

defs	:	/*  empty  */
	|	defs  def
	;

def	:	START  IDENTIFIER
	|	UNION  {  \f2Copy union  definition  to  output\f1  }
	|	LCURL  {  \f2Copy  C  code  to  output  file\f1   }  RCURL
	|	ndefs  rword  tag  nlist
	;

rword	:	TOKEN
	|	LEFT
	|	RIGHT
	|	NONASSOC
	|	TYPE
	;

tag	:	/*  empty:  union  tag  is  optional  */
	|	\'<\'  IDENTIFIER  \'>\'
	;

nlist	:	nmno
	|	nlist  nmno
	|	nlist  \',\'  nmno
	;

nmno	:	IDENTIFIER		/*  NOTE:  literal  illegal  with  %type  */
	|	IDENTIFIER  NUMBER      /*  NOTE:  illegal  with  %type  */
	;

	/*  rules  section  */

rules	:	C_IDENTIFIER  rbody  prec
	|	rules  rule
	;

rule	:	C_IDENTIFIER  rbody  prec
	|	'|'  rbody  prec
	;

rbody	:	/*  empty  */
	|	rbody  IDENTIFIER
	|	rbody  act
	;

act	:	\'{\'  {  \f2Copy  action,  translate  $$,  etc.\f1  }  \'}\'
	;

prec	:	/*  empty  */
	|	PREC  IDENTIFIER
	|	PREC  IDENTIFIER  act
	|	prec  \';\'
	;
.fi
.bp
