*
********
*
DCMDR	  BSR	  PAREND	ENDE DER PARAMETERLISTE?
	  BNE	  FALCMD	NEIN, DANN FEHLER
*
	  MOVE.B  D0,CMDPT	KOMMANDOPOINTER WEGSCHREIBEN
	  CLR.L   A2		ANFANGEN MIT REGISTER NUMMER 0
	  MOVEQ   #4,D3 	SCHLEIFENZAEHLER 1
DCMDRLN   MOVEQ   #3,D4 	SCHLEIFENZAEHLER 2
	  CMPI.B  #1,D3 	VORLETZTE ZEILE?
	  BNE	  DCMDRLN1	NEIN, DANN 4 REGISTER AUSGEBEN
*
	  SUBQ.L  #1,D4 	SONST EIN REGISTER WENIGER
DCMDRLN1  BSR	  PUTCRLF	NEUE ZEILE
DCMDREG   BSR	  PUTNAME	REGISTERNAMEN AUSGEBEN
	  BSR	  PUTREG	INHALT AUSGEBEN
	  BSR	  PUTBLANK	NOCH EIN BLANK HINTERHER
	  ADDQ.L  #1,A2 	NAECHSTES REGISTER
	  DBRA	  D4,DCMDREG	ZEILE FERTIG?
*
	  DBRA	  D3,DCMDRLN	ALLE REGISTER FERTIG?
*
	  BSR	  TRANSNOR	DANN TRANSMITTERSTATUS NORMIEREN
	  BRA	  EXECCMD	UND NAECHSTES KOMMANDO AUSFUEHREN
###############################################################################
	  MOVEA.W #MCMDMKO,A3	ADRESSE ZEILENKOPFUNTERPROGRAMM
	  MOVEA.W #MCMDMST,A4	ADRESSE WEGSPEICHERUNTERPROGRAMM
	  MOVEA.W #MCMDMINC,A5	ADRESSE ZEIGER INKREMENT
	  MOVEA.W #MCMDMDEC,A6	ADRESSE ZEIGER DEKREMENT
	  BSR	  MCMDLOOP	DIALOGUNTERPROGRAMM
	  BRA	  EXECCMD	NAECHSTES KOMMANDO
*
********
*
MCMDR	  CLR.L   A2		ANFANGEN MIT REGISTERNUMMER 0
MCMDRLO   BSR	  GETPAR	PARAMETER HOLEN
	  BMI	  FALCMD	UNGUELTIGER PARAMETER?
*
	  BSR	  MCMDRST	NEIN, DANN WEGSPEICHERN
	  BSR	  MCMDRINC	NAECHSTES REGISTER
	  BEQ	  MCMDRPE	ENDE DER REGISTERLISTE?
*
	  BSR	  PARFORT	NEIN, DANN FORTSETZUNG DER PARAMETERLISTE?
	  BEQ	  MCMDRLO	JA, DANN NAECHSTEN PARAMETER
*
MCMDRPE   MOVE.B  D0,CMDPT	SONST KOMMANDOPOINTER WEGSPEICHERN
	  CMPI.B  #'.',D1	ENDE KOMMANDO?
	  BEQ	  EXECCMD	DANN NAECHSTES KOMMANDO
*
	  BSR	  PAREND	ENDE DER PARAMETERLISTE?
	  BNE	  FALCMD	NEIN, DANN FALSCHES KOMMANDO
*
	  MOVEA.W #MCMDRKO,A3	ADRESSE ZEILENKOPFUNTERPROGRAMM
	  MOVEA.W #MCMDRST,A4	ADRESSE WEGSPEICHERUNTERPROGRAMM
	  MOVEA.W #MCMDRINC,A5	ADRESSE INKREMENTUNTERPROGRAMM
	  MOVEA.W #MCMDRDEC,A6	ADRESSE DEKREMENTUNTERPROGRAMM
	  BSR	  MCMDLOOP	DIALOGUNTERPROGRAMM AUFRUFEN
	  BRA	  EXECCMD	NAECHSTES KOMMANDO
###############################################################################
*******************************************************************************
*									      *
*	  P U T N A M E 	GIBT EINEN REGISTERNAMEN AUS		      *
*									      *
*	  EINGABEPARAMETER   : A2 = REGISTERNUMMER (0 - 18)		      *
*	  AUSGABEPARAMETER   : -					      *
*	  GEAENDERTE REGISTER: D0, A0, CCR				      *
*									      *
*******************************************************************************
*
PUTNAME   MOVE.L  A2,D0 	REGISTERNUMMER NACH D0
	  LSL.L   #2,D0 	OFFSET IN DER TABELLE BERECHNEN
	  MOVEA.W #REGTAB,A0	TABELLENANFANG LADEN
	  ADDA.L  D0,A0 	OFFSET ADDIEREN
	  BSR	  PUTSTR	UND TEXT AUSGEBEN
	  RTS			ANSCHLIESSEND ZURUECK
*
********  ENDE	  PUTNAME	********
*
*******************************************************************************
*									      *
*	  P U T R E G		GIBT EINEN REGISTERINHALT AUS DEN RETTUNGS-   *
*				BEREICH AUS				      *
*									      *
*	  EINGABEPARAMETER   : A2 = REGISTERNUMMER (0 - 18)		      *
*	  AUSGABEPARAMETER   : -					      *
*	  GEAENDERTE REGISTER: D0, D1, A0, CCR				      *
*									      *
*******************************************************************************
*
PUTREG	  BSR	  REGADR	REGISTERADRESSE IM RETTUNGSBEREICH BERECHNEN
	  BEQ	  PUTSR 	STATUSREGISTER? DANN SONDERBEHANDLUNG
*
	  MOVE.L  (A0),D1	REGISTERINHALT LADEN
	  BSR	  PUTLWORD	UND AUSGEBEN
PUTREGE   BSR	  PUTBLANK	2 BLANKS
	  BSR	  PUTBLANK	AUSGEBEN
	  RTS			UND ZURUECK
********
*
PUTSR	  MOVE.W  (A0),D1	STATUSREGISTERINHALT LADEN
	  BSR	  PUTWORD	UND AUSGEBEN
	  MOVEQ   #3,D1 	4 BLANKS
PUTSR1	  BSR	  PUTBLANK	AUSGEBEN
	  DBRA	  D1,PUTSR1	SCHLEIFE ZU ENDE?
*
	  BRA	  PUTREGE	DANN ZURUECK
*
********  ENDE	  PUTREG	********
*
*******************************************************************************
*									      *
*	  R E G A D R		BERECHNET DIE REGISTERADRESSE IM RETTUNGS-    *
*				BEREICH 				      *
*									      *
*	  EINGABEPARAMETER   : A2 = REGISTERNUMMER (0 - 18)		      *
*	  AUSGABEPARAMETER   : Z - FLAG GESETZT BEI STATUSREGISTER	      *
*	  GEAENDERTE REGISTER: D0, A0, CCR				      *
*									      *
*******************************************************************************
*
REGADR	  MOVEA.L #SAVEREG,A0	BASISADRESSE DES REGISTERRETTUNGSBEREICHES
	  MOVE.L  A2,D0 	REGISTERNUMMER NACH D0
	  LSL.L   #2,D0 	*4 (LANGWORT)
	  ADDA.L  D0,A0 	ZUR BASISADRESSE ADDIEREN
	  CMPA.W  #18,A2	PC?
	  BNE	  REGADRE	NEIN, DANN ZUM ENDE
*
	  SUBQ.L  #2,A0 	SONST 2 SUBTRAHIEREN (WEGEN STATUSREGISTER)
REGADRE   CMPA.W  #17,A2	STATUSREGISTER?
	  RTS			ZURUECK
*
********  ENDE	  REGADR	********
*
###############################################################################
*******************************************************************************
*									      *
*	  O P T I O N R 	WERTET DIE OPTION R AUS 		      *
*									      *
*	  EINGABEPARAMETER   : A1 = ZEIGER AUF KOMMANDOPUFFER		      *
*			       D0 = ZEIGER IM  KOMMANDOPUFFER		      *
*	  AUSGABEPARAMETER   : D0 = ZEIGER IM  KOMMANDOPUFFER AUF NAECHSTES Z.*
*			       Z - FLAG GESETZT BEI OPTION R		      *
*	  GEAENDERTE REGISTER: D0, A0, CCR				      *
*									      *
*******************************************************************************
*
OPTIONR   CMPI.B  #'R',D1	'R'?
	  BNE	  OPTIONRE	NEIN, DANN ENDE
*
	  ADDQ.L  #1,D0 	SONST ZEIGER ERHOEHEN
	  MOVE.B  0(A1,D0.L),D1 NAECHSTES ZEICHEN LADEN
	  CMP.B   D1,D1 	Z - FLAG SETZEN
OPTIONRE  RTS			UND ZURUECK
*
********  ENDE	  OPTIONR	********
*
###############################################################################
REGTAB	  DC.B	  'D0 ',':'+MB
	  DC.B	  'D1 ',':'+MB
	  DC.B	  'D2 ',':'+MB
	  DC.B	  'D3 ',':'+MB
	  DC.B	  'D4 ',':'+MB
	  DC.B	  'D5 ',':'+MB
	  DC.B	  'D6 ',':'+MB
	  DC.B	  'D7 ',':'+MB
	  DC.B	  'A0 ',':'+MB
	  DC.B	  'A1 ',':'+MB
	  DC.B	  'A2 ',':'+MB
	  DC.B	  'A3 ',':'+MB
	  DC.B	  'A4 ',':'+MB
	  DC.B	  'A5 ',':'+MB
	  DC.B	  'A6 ',':'+MB
	  DC.B	  'A7S',':'+MB
	  DC.B	  'A7U',':'+MB
	  DC.B	  'SR ',':'+MB
	  DC.B	  'PC ',':'+MB
*